Atom portability


#1

Hello, I know some of you have been wanting to make atom portable enough to be used on a pendrive, and I was able to create a batch file that is able to make it portable.
The link to the file is here: https://gist.github.com/GGG-KILLER/2851d305302945f69530

How to install:

  1. Put the batch inside a file called Atom.bat
  2. Extract the atom-windows.zip on the same directory as the batch
  3. Run the batch.

The batch sets up the filesystem by itself, so there’s no need to do anything apart from running it.

For those who don’t want to go on github to get the file, the source code is here:

@echo off
:: Get current drive's letter.
set a=%~dp0

echo Base path: %a%

:: Environment vars setting
:varsetting
set ATOM_HOME=%a%\Atom\data
set USERPROFILE=%ATOM_HOME%
set APPDATA=%USERPROFILE%\AppData

echo ATOM_HOME: %ATOM_HOME%
echo USERPROFILE: %USERPROFILE%
echo APPDATA: %APPDATA%


:: Filesystem checking.
:fscheck
if not exist "%a%\Atom" (
	echo [ERROR]Atom folder not found.
	goto error
)

if not exist "%a%\Atom\atom.exe" (
	echo [ERROR]Atom executable not found.
	goto error
)
if not exist "%ATOM_HOME%" mkdir "%ATOM_HOME%"
if not exist "%USERPROFILE%\AppData" mkdir "%USERPROFILE%\AppData"
if not exist "%USERPROFILE%\AppData\Roaming" mkdir "%USERPROFILE%\AppData\Roaming"
if not exist "%USERPROFILE%\Desktop" mkdir "%USERPROFILE%\Desktop"
if not exist "%USERPROFILE%\Desktop\Fake Desktop" echo "">"%USERPROFILE%\Desktop\Fake Desktop"

:: Go to atom's folder and launch it.
:launch
cd Atom
start "" atom.exe
goto exit

:error
echo [ERROR]Atom folder MUST be in %a%, named Atom and atom's executable MUST be named atom.exe
set /p m=Press any key to leave...
goto exit

:exit

#2

Is it fully portable to any platform? I want a portable version for linux. Because i cant install anything on that pc. Thx if reply.